TITLE    'Profili termici in un condotto '     { CondottiA.pde }
SELECT
errlim=1e-3
COORDINATES
ycylinder('r','z')
VARIABLES
vz      p	T	vr
DEFINITIONS
r1=5.0e-3
L=5*r1
vz0=1e-1
visc=2.5e-5
dens=0.785	
cond=0.0363	
Cp=1020	
rcp=dens*Cp
T0=300	{ Temperatura di ingresso }
Tw=350  { Temperatura di parete }

 v=vector( vr, vz)        vm=magnitude( v)

Re=dens* vz0*2*r1/ visc   { Numero di Reynolds }
Pr=Cp*visc/cond	             { Numero di Prandtl }

theta=(T-Tw)/(T0-Tw)     { Temperatura adimensionale }

Lcin=2*r1*0.05*Re        { Lunghezza di imbocco cinematica}
Lter=2*r1*0.05*Re*Pr     { Lunghezza di imbocco termica}


dTsudr=dr(T)
dvsudr=dr(vz)

EQUATIONS
vr: dr(p)- visc*[ dr(1/r*dr(r*vr))+ dzz(vr)]+dens*(vr*dr(vr)+vz*dz(vr))=0
vz: dz(p)- visc*[ 1/r*dr(r*dr(vz))+ dzz(vz)]+dens*(vr*dr(vz)+vz*dz(vz))=0
p: 1/r*dr( r*dr(p))+ dzz(p)- 1e6*visc/L^2* div(v)=0		{Sostituisce l'equazione di continuitā}		
T: cond*[ 1/r*dr(r*dr(T))+ dzz(T)]- rcp*[ vr*dr( T)+ vz*dz( T)]=0

BOUNDARIES
region 'domain' start 'outer' (0,0)
natural(vr)=0   	
value(vz)=vz0   	
value(T)=T0
natural(p)=0  	
line to (r1,0) { In }
value(vr)=0   	
value(vz)=0   	
value(T)=Tw				
natural(p)=0 	
line to (r1,L) { Wall }
value(vr)=0   	
natural(vz)=0 	
natural(T)=normal(cond*grad(T))		{non pone condizioni. Dice in sostanza: il flusso termico č uguale al flusso termico}	
value(p)=0  	 {p=0 all'uscita}
line to (0,L) { Out }
value(vr)=0   	
natural(vz)=0   	
natural(T)=0				
natural(p)=0   	
line to close { Axis }

MONITORS
contour( vz) zoom(0,0,r1,2*Lcin) report(Lcin/r1/2)
contour( vr)
surface( p)
contour( Theta) zoom(0,0,r1,2*Lter) report(Lter/r1/2)
vector( v) report(Re)
surface(T)
contour( div(v))
elevation( vz) from (0,0) to (r1,0)
elevation( vz) from (0,Lcin) to (r1,Lcin)
elevation( T) from (0,Lter/2) to (r1,Lter/2)
elevation( vz) from (0,0) to (0,L)
elevation( T) from (0,0) to (0,L)
elevation( vz, -5e-3*dr( vz)) from (0,L) to (r1,L)


PLOTS
contour( vz) zoom(0,0,r1,2*Lcin) report(Lcin/r1/2)
contour( vr)
surface( p)
contour( Theta) zoom(0,0,r1,2*Lter) report(Lter/r1/2)
vector( v) report(Re)
surface(T)
contour( div(v))
elevation( vz) from (0,0) to (r1,0)
elevation( vz) from (0,Lcin) to (r1,Lcin)
elevation( T) from (0,Lter/2) to (r1,Lter/2)
elevation( vz) from (0,0) to (0,L)
elevation( T) from (0,0) to (0,L)
elevation( vz, -5e-3*dr( vz)) from (0,L) to (r1,L)

transfer(T,vz,vr,p,dTsudr,dvsudr) file="transfer.dat" {trasferisce i dati a "CondottiB"}
transfer(L,r1,visc,dens,Cp,cond,T0,Tw) file="data.dat" {trasferisce i dati a "CondottiB"}



END