TITLE     'Moto in condotti con generazione viscosa'       { Dissipation.pde }
SELECT
errlim=1e-3
COORDINATES
ycylinder('r','z')
VARIABLES
vz      p	     T	vr
DEFINITIONS
r1=5.0e-4    L=10*r1
vmedia=1e-2
vz0=2*vmedia*(1-(r/r1)^2) { Profilo di velocitˆ sviluppato }
visc=4e3     dens=500	cond=0.6	Cp=2000	rcp=dens*Cp { Polipropilene}
T0=300	{Temperatura di ingresso}
Tw=300 {Temperatura di parete}

{Profili di temperatura a varie distanze dall'imbocco}
TA=eval(T,r,L/10)
TB=eval(T,r,2*L/10)
TC=eval(T,r,3*L/10)
TD=eval(T,r,4*L/10)
TE=eval(T,r,5*L/10)
TF=eval(T,r,6*L/10)
TG=eval(T,r,7*L/10)
TH=eval(T,r,8*L/10)
TI=eval(T,r,9*L/10)
TJ=eval(T,r,10*L/10)

v=vector( vr, vz)        vm=magnitude( v)
Re=dens* vmedia*r1/ visc {Numero di Reynolds}
Pr=Cp*visc/cond		{Numero di Prandtl}
div_v=1/r*dr(r*vr)+ dz(vz)

natp=0   
dTsudr=dr(T)
dvsudr=dr(vz)
Fi=2*((dr(vr))^2+(vr/r)^2+(dz(vz)))^2+(dz(vr)+dr(vz))^2   { termine di generazione viscosa }


EQUATIONS
vr: dr(p)- visc*[ dr(1/r*dr(r*vr))+ dzz(vr)]+dens*(vr*dr(vr)+vz*dz(vr))=0
vz: dz(p)- visc*[ 1/r*dr(r*dr(vz))+ dzz(vz)]+dens*(vr*dr(vz)+vz*dz(vz))=0
p: 1/r*dr( r*dr(p))+ dzz(p)- 1e6*visc/L^2* div_v=0
T: -cond*[ 1/r*dr(r*dr(T))+ dzz(T)]+ rcp*[ vr*dr( T)+ vz*dz( T)]-visc*Fi=0

BOUNDARIES
region 'domain' start 'outer' (0,0)
value(vr)=0   	
value(vz)=vz0   	
value(T)=T0	
natural(p)=natp  	line to (r1,0) { In }
value(vr)=0   	
value(vz)=0   	
!value(T)=Tw	{Temperatura fissata alla parete}
natural(T)=0	{Parete adiabatica}
natural(p)=natp 	
line to (r1,L) { Wall }
value(vr)=0   	
natural(vz)=0 	
natural(T)=normal(cond*grad(T))	
value(p)=0  	
line to (0,L) { Out }
value(vr)=0   	
natural(vz)=0   	
natural(T)=0	
natural(p)=0   	
line to close { Axis }

MONITORS
contour( vz)  zoom(0,0,r1,L)
contour( vr)  zoom(0,0,r1,L)
contour( p) painted  zoom(0,0,r1,L)
contour( T) zoom(0,0,r1,L)
vector( v) zoom(0,0,r1,L)
surface(T) zoom(0,0,r1,L)
contour( div_v)   zoom(0,0,r1,L)
elevation( vz) from (0,0) to (r1,0)
elevation( vz) from (0,0) to (r1,0)
elevation( T,TA,TB,TC,TD,TE,TF,TG,TH,TI,TJ) from (0,0) to (r1,0) { Profili termici }
elevation( vz) from (0,0) to (0,L)
elevation( T) from (0,0) to (0,L) as "Temperatura all'asse"
elevation(p) from(0,0) to (0,L)


PLOTS
contour( vr)  zoom(0,0,r1,L)
contour( p) painted  zoom(0,0,r1,L)
contour( T) zoom(0,0,r1,L)
vector( v) zoom(0,0,r1,L)
surface(T) zoom(0,0,r1,L)
contour( div_v)   zoom(0,0,r1,L)
elevation( vz) from (0,0) to (r1,0)
elevation( vz) from (0,0) to (r1,0)
elevation( T,TA,TB,TC,TD,TE,TF,TG,TH,TI,TJ) from (0,0) to (r1,0) { Profili termici }
elevation( vz) from (0,0) to (0,L)
elevation( T) from (0,0) to (0,L) as "Temperatura all'asse"
elevation(p) from(0,0) to (0,L)

transfer(T,vz,vr,p,dTsudr,dvsudr) file="transfer.dat" {trasferisce i dati a "DissipationB"}
transfer(L,r1,visc,dens,Cp,cond,T0,Tw) file="data.dat" {trasferisce i dati a "DissipationB"}




END