TITLE     'Moto in condotti con generazione viscosa'       { Dissipation.pde }
SELECT

COORDINATES
 ycylinder('r','z')

VARIABLES
ITb	Por

DEFINITIONS
 transfermesh('transfer.dat',T,vz,vr,p,dTsudr,dvsudr)  {Importa i dati da "DissipationA"}


   v=vector( vr, vz)        vm=magnitude( v)
   vz0=globalmax(vm)/2

 r1=5.0e-4    L=10*r1
visc=4e3     dens=500	cond=0.6	Cp=2000	rcp=dens*Cp
T0=eval(T,0,0)	{ Temperatura di ingresso }
Tw=eval(T,r1,z)  { Temperatura di parete }
P0=eval(p,0,0) { Pressione di ingresso }
Pc=eval(p,0,z) { Pressione all'asse }
Tad=(P0-Pc)/rcp+T0

Tb=ITb/Por
vav=Por/(PI*r1^2)

   Re=dens* vz0*2*r1/ visc   { Numero di Reynolds }
   Pr=Cp*visc/cond  { Numero di Prandtl }

   div_v=1/r*dr(r*vr)+ dz(vz)     curl_phi=dz(vr)- dr(vz)
   unit_r=vector(1,0)     unit_z=vector(0,1)
   nr=normal( unit_r)     nz=normal( unit_z)

q=Eval(-cond*dTsudr,r1,z)	 	tau=Eval(-visc*dvsudr,r1,z)
h=abs(q/(Tb-Tw))			f=tau/(1/2*dens*vz0^2)
hfinal=eval(h,r1,L)		ffinal=eval(f,r1,L)	
GrL=Re*Pr*2*r1/L
NuL=hfinal*2*r1/cond


EQUATIONS
ITb:	dr(ITb)-2*PI*r*vz*T= 1e-16*dzz(ITb)
Por:	 dr(Por)-2*PI*r*vz= 1e-16*dzz(Por)

BOUNDARIES
region 'domain' start 'outer' (0,0)
line to (r1,0) { In }
natural(ITb)=0
natural(Por)=0	
line to (r1,L) { Wall }
natural(ITb)=0
natural(Por)=0	
 line to (0,L) { Out }
value(ITb)=0  	
value(Por)=0
 line to close { Axis }

MONITORS
elevation(Tb) from(r1,0) to (r1,L)
elevation(vav,vz0) from(r1,0) to (r1,L)
elevation(q) from(r1,0) to (r1,L)
elevation(f) from(r1,0) to (r1,L)


 PLOTS
elevation(Tb,Tad) from(r1,0) to (r1,L) export format "#y#b#1" file="Tbtable.txt"
elevation(q) from(r1,0) to (r1,L)  export format "#y#b#1" file="qtable.txt"
elevation(h) from(r1,0) to (r1,L) export format "#y#b#1" file="htable.txt"
elevation(f) from(r1,0) to (r1,L) export format "#y#b#1" file="ftable.txt"
elevation(vav,vz0) from(r1,0) to (r1,L)
elevation(q) from(r1,0) to (r1,L)
elevation(f) from(r1,0) to (r1,L)
surface(T)  export format "#x#y#b#1" file="T.txt"
vector(v) zoom(0,0,r1,r1)

summary
report(Re)
report(Pr)
report(GrL)
report(NuL)
report(hfinal)
report(ffinal)

END