TITLE
 'Transitorio termico in una lastra rettangolare'     { Slab2d.pde }
COORDINATES
cartesian2
VARIABLES
 Temp(0.01)              { Temperatura }
SELECT
!Errlim=1e-2
DEFINITIONS
k=0.6	dens=1000	Cp=4100	alfa=k/dens/Cp	{ parametri fisici}
Ti=350	Tw=300		deltadiT=(Ti-Tw)	  { Temperature iniziali e alla parete}
Lx=.1	Ly=Lx	  { semi-lunghezze dei lati }
Tbrevi=Tw+(Ti-Tw)*ERF((Lx-x)/(4*alfa*t)^.5)	  { soluzione per tempi brevi (teoria della penetrazione) }
*erf((Ly-y)/(4*alfa*t)^.5)	  {anteporre un punto esclamativo se la lastra e' ad una sola dimensione }
tpen=(Lx/4)^2/alfa	{tempo di penetrazione lungox}
Tlunghi=Tw+(Ti-Tw)*4/PI*cos(PI/2*(x)/Lx)*exp(-(PI^2/4*t*alfa/Lx^2))  { soluzione per tempi lunghi (primo termine della serie infinita) }
*4/PI*cos(PI/2*(y)/Ly)*exp(-(PI^2/4*t*alfa/Ly^2)) {anteporre un punto esclamativo se la lastra e' ad una sola dimensione }
tlong=Lx^2/alfa/PI^2	{tempo a cui diventa valida l'approx al primo termine della serie (lungox)}
INITIAL VALUES
Temp=Ti
EQUATIONS
  dt(Temp)-alfa*del2(Temp)=0 { diffusione del calore}

BOUNDARIES
  REGION 1
    START(-Lx,-Ly)
value(Temp)=Tw		  { sup. inferiore }
!natural(Temp)=0		  { se la lastra e' ad una sola dimensione }
    LINE TO (Lx,-Ly)
value(Temp)=Tw		 { sup. destra }
LINE TO (Lx,Ly)
value(Temp)=Tw		 { sup. superiore }
!natural(Temp)=0		  { se la lastra e' ad una sola dimensione }
LINE TO (-Lx,Ly)
value(Temp)=Tw		 { sup. sinistra }
LINE TO CLOSE
TIME
0 TO 48*3600    { durata totale: 1 giorno }
MONITORS
for t = 0 by 900  to 48*3600	{ risultati ogni 15 minuti }
Surface(Temp)zoom(0,0,Lx,Ly)
Surface(Tbrevi) zoom(0,0,Lx,Ly)
Surface(Tlunghi) zoom(0,0,Lx,Ly)
Surface((Temp-Tbrevi)/deltadiT) zoom(0,0,Lx,Ly) report(tpen) {scarto percentuale rispetto a sol. a tempi brevi }
Surface((Temp-Tlunghi)/deltadiT) zoom(0,0,Lx,Ly)  report(tlong) {scarto percentuale rispetto a sol. a tempi lunghi }
PLOTS
Surface(Temp)
END