TITLE 'Due solidi a temperature diverse messi a contatto'     {SolidiAContatto.pde}

COORDINATES cartesian1  { il problema e' mono-dimensionale }

VARIABLES
  temp              {temperatura}

SELECT
errlim=1e-5


DEFINITIONS    { parameter definitions }
Tinf1=400
Tinf2=300
xmax=1     { spessore totale delle due lastre }
xslab=xmax/3 { spessore della lastra di materiale "1" }
xstar=xmax-xslab  { spessore della lastra di materiale "2" }
kappa	alfa     { proprieta' rilevanti dei solidi (da definire) }
kappa1=60.5	 { conducibilita' del solido "1" }
kappa2=237	{ conducibilita' del solido "2" }
alfa1=17.7e-6  { diffusivita' del solido "1" }
alfa2=97.1e-6 { diffusivita' del solido "2" }
e1=kappa1/alfa1^.5 { effusivita' del solido "1" }
e2=kappa2/alfa2^.5 { effusivita' del solido "2" }
f=-kappa*dx(temp) { flusso termico }
Tstar=(e1*Tinf1+e2*Tinf2)/(e1+e2)   { temperatura di interfaccia secondo soluzione analitica }
Tsol1=tstar-(tstar-tinf1)*ERF((x-xstar)/(4*alfa1*t)^.5) { soluzione analitica }
Tsol2=tstar+(tstar-tinf2)*ERF((x-xstar)/(4*alfa2*t)^.5) { soluzione analitica }
Tsol=if x<xstar then Tsol2 else Tsol1  { soluzione analitica }
fsol=-kappa*dx(Tsol) { flusso termico analitico}
Tpen1=xslab^2/alfa1/16   { tempo limite di penetrazione nella lastra 1}
 Tpen2=xstar^2/alfa2/16   { tempo limite di penetrazione nella lastra 2}

 INITIAL VALUES
temp=if x<xstar then Tinf2 else Tinf1 { valori iniziali }

EQUATIONS
div(kappa*grad(temp))=kappa/alfa*dt(temp) { diffusione del calore }


BOUNDARIES
  REGION 1       { in tutto il dominio (entrambi i materiali) }
 kappa=kappa1 { proprietˆ del solido "1" }
alfa=alfa1
   START(0)
 Natural(temp)=0 { parete adiabatica a sinistra }
 LINE TO (xmax)
 Natural(temp)=0 { parete adiabatica a destra }

  REGION 2  { solo in una porzione del dominio (x<xstar) }
  kappa=kappa2 { proprieta' del solido "2"}
alfa=alfa2

   START(0,0)
 LINE TO (xstar)


TIME 0 TO 10000    { transitorio }

MONITORS         { progresso }
for t = 0 by 5  to 1000
elevation(temp,Tsol) from (0) to (xmax)  as "Temp" report(min(Tpen1,Tpen2))
elevation(f,fsol) from (0) to (xmax)  as "Flux"

for t=0.1
SUMMARY
 REPORT(t) as "time"
 REPORT(e1) as "Effusivita' solido 1"
 REPORT(e2) as "Effusivita' solido 2"
 REPORT(Tpen1) as "Tempo limite di penetrazione nella lastra 1"
 REPORT(Tpen2) as "Tempo limite di penetrazione nella lastra 2"
 REPORT(val(f,0))
 REPORT(val(temp,0))
 REPORT(val(temp,xstar))
 REPORT(val(temp,xmax))
 REPORT(INTEGRAL(kappa/alfa*temp)/INTEGRAL(kappa/alfa))


PLOTS            { save result displays }



HISTORIES   { grafici nel tempo }
history(INTEGRAL(kappa/alfa*temp)/INTEGRAL(kappa/alfa),INTEGRAL(kappa/alfa*tsol)/INTEGRAL(kappa/alfa)) as "Tmedia"
History(temp,tstar) at (xstar) as "Temp at x=x*"



END