TITLE 'Assorbimento con reazione omogenea'     { diffusion&reaction }
 
COORDINATES cartesian1 
 
VARIABLES     
 cAr  cBr        {concentrazioni di A=specie che diffonde, e B=specie già presente}
 
 SELECT        
errlim=5e-3
 
DEFINITIONS    
tcontact=1e3 { tempo di contatto }
Das = 2e-9   { diffusività di A }
Dbs = Das*1 { diffusività di B }
Lx = 4*(Das*tcontact)^.5    { spessore dello strato (basato sulla teoria della penetrazione }
cAi =100               { concentrazione di A alla parete }
cA0=0	 { concentrazione iniziale di A  }
cB0 = cAi*10 { concentrazione iniziale di B  }
!k=1e1 !reazione istantanea
k=1e-5 !reazione lenta
 
coeffStecB = 1 { A+coeffStecB B -> C  }
rAr=k*cAr*cBr	{ velocità di reazione di A}
rBr = rAr*coeffStecB { velocità di reazione di B}
 
cApen=cAi*(1-erf(x/sqrt(4*Das*t)))  { in assenza di reazione}
cAist=max(cAi*(1-(1+cB0/(cAi*coeffStecB)*sqrt(Dbs/Das))*erf(x/sqrt(4*Das*t))),0) { per reazione istantanea}
 
INITIAL VALUES
 
cAr=cA0
cBr = cB0
 
EQUATIONS       
 
cAr : dt( cAr) = Das*dx(dx( cAr)) - rAr
cBr : dt( cBr) = Dbs*dx( dx( cBr)) - rBr
 
BOUNDARIES       
REGION 1      
 
    START(0)   
 
 point value ( cAr)=cAi
 natural( cBr) = 0
 
    LINE TO (Lx)
 
 natural(cAr) = 0
 natural( cBr) = 0
 
 TIME 0 TO 2*tcontact   
 
MONITORS        
!for t = 0 by 1 to 2*tcontact
for cycle=1
 
 elevation( cAr , cBr) from (0) to (Lx) as "concentrazione"
 elevation( cAr , cApen, cAist) from (0) to (Lx) as "confronti"
 
 
END